perl Socket编程

perl网络编程可能是令大多数人头疼，如何快速掌握perl网络编程能？答案是看样例，然后自己编写。
以下给出几段使用Socket及IO::Socket编写的Server/client，他们能实现最简单但是却最基本的任务，包括一个forking/accept的模型。通过下面几个样例的学习，希望你能够掌握perl网络编程。
样例1：从服务器端读取一行信息然后返回

perl

#!/usr/bin/perl -w
# tcp_socket_cli.pl
use strict;
use Socket;
my $addr = $ARGV[0] || '127.0.0.1';
my $port = $ARGV[1] || '3000';
my $dest = sockaddr_in($port, inet_aton($addr));
my $buf = undef;
socket(SOCK,PF_INET,SOCK_STREAM,6) or die "Can't create socket: $!";
connect(SOCK,$dest)                or die "Can't connect: $!";
my $bs = sysread(SOCK, $buf, 2048); # try to read 2048
print "Received $bs bytes, content $buf\n"; # actually get $bs bytes
close SOCK;

执行结果：
perl tcp_socket_cli.pl localhost 25
Received 41 bytes, content 220 ESMTP Postfix - ExtMail 0.12-hzqbbc
TCP 服务端 Socket模块, forking/accept模型
样例2：一个多进程的TCP服务器，sample中实现了daytime的功能

perl

#!/usr/bin/perl -w
# tcp_socket_dt_srv.pl
use strict;
use Socket;
use IO::Handle;
use POSIX qw(WNOHANG);
my $port     = $ARGV[0] || '3000';
my $proto    = getprotobyname('tcp');
$SIG{'CHLD'} = sub {
    while((my $pid = waitpid(-1, WNOHANG)) >0) {
        print "Reaped child $pid\n";
    }
};
socket(SOCK, AF_INET, SOCK_STREAM, getprotobyname('tcp')) or die "socket() failed: $!";
setsockopt(SOCK,SOL_SOCKET,SO_REUSEADDR,1) or die "Can't set SO_REUSADDR: $!" ;
my $my_addr = sockaddr_in($port,INADDR_ANY);
bind(SOCK,$my_addr)    or die "bind() failed: $!";
listen(SOCK,SOMAXCONN) or die "listen() failed: $!";
warn "Starting server on port $port...n";
while (1) {
    next unless my $remote_addr = accept(SESSION,SOCK);
    defined(my $pid=fork) or die "Can't fork: $!n";
    if($pid==0) {
        my ($port,$hisaddr) = sockaddr_in($remote_addr);
        warn "Connection from [",inet_ntoa($hisaddr),",$port]n";
        SESSION->autoflush(1);
        print SESSION (my $s = localtime);
        warn "Connection from [",inet_ntoa($hisaddr),",$port] finishedn";
        close SESSION;
        exit 0;
    }else {
        print "Forking child $pid\n";
    }
}
close SOCK;

利用上述tcp_socket_cli.pl访问该server的执行结果：
[hzqbbc@local misc]$ perl tcp_socket_dt_srv.pl
Starting server on port 3000...
Connection from [127.0.0.1,32888]
Connection from [127.0.0.1,32888] finished
Reaped child 13927
Forking child 13927
样例3：使用IO::Socket模块

perl

#!/usr/bin/perl -w
# tcp_iosocket_cli.pl
use strict;
use IO::Socket;
my $addr = $ARGV[0] || '127.0.0.1';
my $port = $ARGV[1] || '3000';
my $buf = undef;
my $sock = IO::Socket::INET->new(
PeerAddr => $addr,
PeerPort => $port,
Proto    => 'tcp')
or die "Can't connect: $!n";
$buf = <$sock>;
my $bs = length($buf);
print "Received $bs bytes, content $buf\n"; # actually get $bs bytes
close $sock;

TCP 服务端, IO::Socket模块, forking/accept模型
样例4：同样的一个daytime

perl

#!/usr/bin/perl
# tcp_iosocket_dt_srv.pl
use strict;
use IO::Socket;
use POSIX qw(WNOHANG);
$SIG = sub {
    while((my $pid = waitpid(-1, WNOHANG)) >0) {
        print "Reaped child $pid\n";
    }
};
my $port     = $ARGV[0] || '3000';
my $sock = IO::Socket::INET->new( Listen    => 20,
LocalPort => $port,
Timeout   => 60*1,
Reuse     => 1)
or die "Can't create listening socket: $!n";
warn "Starting server on port $port...n";
while (1) {
    next unless my $session = $sock->accept;
    defined (my $pid = fork) or die "Can't fork: $!n";
    if($pid == 0) {
        my $peer = gethostbyaddr($session->peeraddr,AF_INET) || $session->peerhost;
        my $port = $session->peerport;
        warn "Connection from [$peer,$port]n";
        $session->autoflush(1);
        print $session (my $s = localtime), "n";
        warn "Connection from [$peer,$port] finishedn";
        close $session;
        exit 0;
    }else {
        print "Forking child $pid\n";
    }
}
close $sock;

现在再介绍使用Socket及IO::Socket模块来进行Unix domain Socket的client/server开发。Unix Domain Socket（简称unix socket）和TCP/UDP等INET类型socket相比起来有几个优点：
1）、安全性高，unix socket只在单机环境中使用，不支持机器之间通信
2）、效率高，执行时的速度约是TCP的两倍，多用于操作系统内部通信（IPC）
3）、支持SOCK_DGRAM，但和UDP不同，前后消息是严格有序的
因此使用Unix socket来设计单机的IPC应用是首选。非常实用。大量的Unix应用软件都使用unix socket来进行程序间通信。
Unix Domain Socket客户端, Socket模块
样例5：使用Unix domain socket的客户端。

perl

#!/usr/bin/perl -w
use strict;
use Socket;
use IO::Handle;
my $path = $ARGV[0] || '/tmp/daytime.sock';
socket(my $sock, PF_UNIX, SOCK_STREAM, 0);
my $sun = sockaddr_un($path);
connect($sock, $sun) or die "Connect: $!n";
$sock->autoflush(1);
my $buf = <$sock>;
my $bs = length($buf);
print "Received $bs bytes, content $buf\n";
close $sock;

Unix Domain Socket 服务端, Socket模块
样例6：使用Unix domain socket实现的daytime服务器。

perl

#!/usr/bin/perl -w
# tcp_socket_dt_srv.pl
use strict;
use Socket;
use IO::Handle;
use POSIX qw(WNOHANG);
my $path     = $ARGV[0] || '/tmp/daytime.sock';
$SIG{'CHLD'} = sub {
    while((my $pid = waitpid(-1, WNOHANG)) >0) {
        print "Reaped child $pid\n";
    }
};
socket(SOCK, PF_UNIX, SOCK_STREAM, 0)
or die "socket() failed: $!";
setsockopt(SOCK,SOL_SOCKET,SO_REUSEADDR,1)
or die "Can't set SO_REUSADDR: $!" ;
unlink $path if -r $path;
bind(SOCK,sockaddr_un($path))    or die "bind() failed: $!";
listen(SOCK,SOMAXCONN)           or die "listen() failed: $!";
warn "Starting server on path $path...n";
while (1) {
    next unless my $sockname = accept(SESSION,SOCK);
    defined (my $pid=fork) or die "Can't fork: $!n";
    if($pid==0) {
        SESSION->autoflush(1);
        print SESSION (my $s = localtime);
        close SESSION;
        exit 0;
    }else {
        print "Forking child $pid\n";
    }
}
close SOCK;

perl Socket编程

延伸阅读

评论

发表评论